Grand Slam 3/Grand Slam 3.iso/030/atccom.arj/MIADFW.ATC

Text File | 1995-08-29 | 10KB | 517 lines

##############################################################################
# This is an atc program which controls a flight from Miami intl. 27L
# to Dallas-Ft. Worth rwy 17R
#
# Use this file together with the point file miadfw.pnt.
#
##############################################################################
#
# Where to find the points used in this program:
#
Points  miadfw.pnt
#
# Use flight levels above this altitude:
#
FLAltitude 18000
#
#
# The next two triggers, will keep telling the pilot to move to Miami until
# the aircraft is within 6 miles from rwy 27.
#

Label again

Message Hello, to start: Move to Miami.
Trigger dist
    Action        GOTO again
     Repeat        21
    Point        FIX:MIARWY27
    Distance    >5
End
Trigger dist
     Repeat        5
    Point        FIX:MIARWY27
    Distance    <6
End
WAIT

#
# Enforce speed restriction below 10000 ft.
#
GOSUB speedlo


Message *Contact clearance delivery on 135.35
Trigger frequency
    Frequency    135.35
End
WAIT

###############################################################################
# MIA, MIAMI SIX DEPARTURE (PILOT NAV)
###############################################################################

#
# Send clearance to the aircraft. The $ on the list message line forces the
# pilot to acknowledge the clearance before the next message is shown.
#
Message    *Flight 18 cleared to Dallas,|
Message via radar vectors to "PHK" "J53" "ORL" "J20" "EIC" "J4" "DFW"|
Message Expect FL 260 10 minutes after departure,|
Message Departure frequency 121.7, squawk 3132
Message $

Message *Please contact Ground control on 121.7
Trigger frequency
    Frequency    121.70
End
WAIT

##############################################################################
Message    *Flight 18, Taxi to runway 27,|
Message Contact Miami tower on 118.9
Trigger frequency
    Frequency    118.90
End
WAIT


Message *$Flight 18, position and hold runway 27Left

Message *Flight 18, fly heading 270,| cleared for takeoff runway 27Left
Control heading
    Heading        270
    Point        FIX:MIARWY27
End
Trigger altitude
    Altitude    >100
End
WAIT

###############################################################################


Message    *Flight 18, Contact Miami departure on 126.85
Trigger frequency
    Frequency    124.22
End
WAIT

#
# Now we create a global altitude control which doesn't contain an altitude
# parameter. This control will follow the value of the Altitude command
# instead.
# In this way, we can assign altitude with the altitude command.
# While this trigger is active, the pilot can request altitude changes.
#
Altitude 5000
GControl altitude
    Name        altctl
End

Message    *Flight 18, radar contact,|
Message Climb to 5000 ft,  continue heading 270
Control heading
    Heading        270
    Point        FIX:MIARWY27
End
Trigger dist
    Point        FIX:MIARWY27
    Distance    >3
End
WAIT

#
# Generate 3 random headings for the aircraft, this is to simulate departure
# radar vectors.
#
Control RHeading
    Point        VOR:PHK
    Action        NEXT
    Delay        30
    Number        3
    InitialMsg    1
    Heading        300
End
WAIT

#
# Ok, now turn the aircraft towards PHK.
#
Control course
     InitialMsg    1
    Point           VOR:PHK
End
Trigger dist
    Point        FIX:MIARWY27
    Distance    >12
End
WAIT

##############################################################################
#
#                            E N R O U T E
#
##############################################################################
Message    *$Proceed direct "PHK" then resume own navigation

#
# Setup frequency change thread.
#
GOSUB frqsetup

Message    *Flight 18, Climb and maintain flight level 260
Altitude FL 260
Control point
    Action        NEXT
    Point           VOR:PHK
End
WAIT

##############################################################################
#  J53
##############################################################################
Control Radial
    Point        VOR:ORL
    Radial        TO 342
    Action        NEXT
End
WAIT

##############################################################################
#  J20
##############################################################################
Control Radial
    Point        VOR:TLH
    Radial        TO 307
    RPrecision    8
    Action         NEXT
End
WAIT

Control Radial
    Point        VOR:MGM
    Radial        TO 311
    RPrecision    10
    Action         NEXT
End
WAIT

Control Radial
    Point        VOR:MEI
    Radial        TO 269
    Action        NEXT
End
WAIT

Control Radial
    Point        VOR:JAN
    Radial        TO 271
    Action        NEXT
End
WAIT

Control Radial
    Point        VOR:EIC
    Radial        TO 267
    Action        NEXT
End
WAIT

##############################################################################
#  J4
##############################################################################

Control Radial
    Point        VOR:EIC
    Radial        FROM 266
End
Trigger dist
    Point        VOR:EIC
    Distance    >50
End
WAIT

Message    *Flight 18, descend and maintain 10000
Altitude 10000
Control Radial
    Point        VOR:EIC
    Radial        FROM 266
End
Trigger dist
    Point        VOR:EIC
    Distance    >75
End
WAIT

##############################################################################
#
#  Blue Rich six arrival (Start at BUJ)
#
##############################################################################
Control Course
     InitialMsg    1
    Point           VOR:BUJ
    Action        NEXT
End
WAIT

Altitude 9000
Message Descend to 9000
Control heading
    InitialMsg    1
    Heading        230
    Point        VOR:BUJ
End
Trigger dist
    Point        VOR:BUJ
    Distance    >10
End
WAIT

Message *Descend and maintain 5000,|Reduce speed to 180
Altitude 5000
Control course
     InitialMsg    1
    Point           FIX:GARZA
End
Trigger dist
    Point        FIX:GARZA
    Distance    <5
End
WAIT

Message    *Descend and maintain 3000,|
Message Maintain heading until intercepting localizer,|
Message Cleared for "ILS" approach runway 17R
Altitude 3000
Trigger point
    Point        FIX:GARZA
End
WAIT


#
# Turn off the global altitude trigger. The pilot cannot request altitude
# changes from now on.
#
Off altctl

Message    *Contact Dallas tower on 126.55
Trigger frequency
    Frequency    126.55
End
WAIT

Message    *Flight 18, cleared to land runway 17R
Trigger altitude
    Altitude    603
End
Trigger Speed
    Speed        <50
End
WAIT

##############################################################################

Message    *Contact Dallas ground on 121.65
Trigger frequency
    Frequency    121.65
End
WAIT

Message    *Flight 18, Take nearest taxiway to parking.
STOP




############################################################################
#
# Handle max speeds below 10000
#
# This is done by three GOSUB labels:
#
#   speedlo: Sets up a global trigger that monitors that the speed is below
#            250 knots.
#            Also sets up a trigger that kicks in when the altitude goes
#            above 10000 ft. When this happen speedhi is called.
#
#   speedhi: Turns off the global speed trigger.
#            Also sets up a trigger that kicks in when the altitude goes
#            below 9500 ft. When this happen speedlo is called.
#
#   speedoff:Turns off the speed triggers.
#
#  Just call the speedlo trigger shortly after takeoff. After this the triggers
#  will monitor the speed as required.
#
#
############################################################################

LABEL speedlo

    GTrigger Altitude
    Name        speedalt
    Altitude    >10000
    Action        gosub speedhi
    End

    GTrigger Speed
    Name        maxspeed
    Speed        >270
    Action        Message    Reduce speed to below 250
    Repeat        20
    End
RETURN


LABEL speedhi

    GTrigger Altitude
    Name        speedalt
    Altitude    <9500
    Action        gosub speedlo
    End

    OFF maxspeed
RETURN

LABEL speedoff
    Off speedalt
    Off maxspeed
RETURN

##############################################################################
#
# Define a chain of GOSUB labels that'll request frequency changes when this
# is necessary. Each of the labels set up a global trigger that wait for the
# relevant condition. When this happen, the trigger gosubs to the next label
# in the sequence.
# In this way, we've created a sort of parallel program that will monitor
# frequency changes.
#
# Note that all the triggers have the same name ("freqtrig"), ATCCOM will
# ensure that only one of these triggers are active at the same time.
#
##############################################################################
LABEL frqsetup
    GTrigger altitude
    Name        freqtrig
    Action        gosub f2
    Altitude    >8000
    End
RETURN

LABEL f2
    Message    *Flight 18, Contact Miami Center on 134.75
    GTrigger frequency
    Name        freqtrig
    Action            gosub f3
    Frequency    134.75
    End
RETURN

LABEL f3
    Message    Flight 18, radar contact
    GTrigger dist
    Name        freqtrig
    Action        gosub f4
    Point        VOR:ORL
    Distance    <20
    End
RETURN

LABEL f4
    Message    *Contact Jacksonville center on 119.10
    GTrigger frequency
    Name        freqtrig
    Action            gosub f5
    Frequency    119.10
    End
RETURN

LABEL f5
    Message    Roger Flight 18
    GTrigger dist
    Name        freqtrig
    Action        gosub f6
    Point        VOR:MGM
    Distance    <40
    End
RETURN

LABEL f6
    Message    *Contact Atlanta center on 119.20
    GTrigger frequency
    Name        freqtrig
    Action            gosub f7
    Frequency    119.20
    End
RETURN

LABEL f7
    Message    Flight 18, radar contact
    GTrigger dist
    Name        freqtrig
    Action        gosub f8
    Point        VOR:MEI
    Distance    <20
    End
RETURN

LABEL f8
    Message    *Contact Memphis center on 119.30
    GTrigger frequency
    Name        freqtrig
    Action            gosub f9
    Frequency    119.30
    End
RETURN

LABEL f9
    Message    Roger Flight 18
    GTrigger dist
    Name        freqtrig
    Action        gosub f10
    Point        VOR:EIC
    Distance    <80
    End
RETURN

LABEL f10
    Message    *Contact Fort Worth center on 119.40
    GTrigger frequency
    Name        freqtrig
    Action            gosub f11
    Frequency    119.40
    End
RETURN

LABEL f11
    Message    Flight 18, Radar contact
    GTrigger dist
    Name        freqtrig
    Action        gosub f12
    Point        VOR:BUJ
    Distance    <10
    End
RETURN


LABEL f12
    Message    *Flight 18,Contact Dallas approach on 119.05
    GTrigger frequency
    Name        freqtrig
    Action            gosub f13
    Frequency    119.95
    End
RETURN

LABEL f13
    Off        freqtrig
    Message    *Flight 18, radar contact,|
    Message    Expect vectors for runway 17R
RETURN